VirtualBox

source: vbox/trunk/doc/manual/docbook-changelog-to-manual-dita.xsl

Last change on this file was 99516, checked in by vboxsync, 12 months ago

manual: scm fix. bugref:10302
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 8.7 KB
Line 
1<?xml version="1.0"?>
2<!--
3 docbook-changelog-to-manual-dita.xsl:
4 XSLT stylesheet for converting the change log from DocBook to Dita.
5-->
6<!--
7 Copyright (C) 2006-2023 Oracle and/or its affiliates.
8
9 This file is part of VirtualBox base platform packages, as
10 available from https://www.virtualbox.org.
11
12 This program is free software; you can redistribute it and/or
13 modify it under the terms of the GNU General Public License
14 as published by the Free Software Foundation, in version 3 of the
15 License.
16
17 This program is distributed in the hope that it will be useful, but
18 WITHOUT ANY WARRANTY; without even the implied warranty of
19 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
20 General Public License for more details.
21
22 You should have received a copy of the GNU General Public License
23 along with this program; if not, see <https://www.gnu.org/licenses>.
24
25 SPDX-License-Identifier: GPL-3.0-only
26-->
27
28<xsl:stylesheet
29 version="1.0"
30 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
31 xmlns:str="http://xsltsl.org/string"
32 >
33
34 <xsl:import href="string.xsl"/>
35 <xsl:import href="common-formatcfg.xsl"/>
36
37 <xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>
38 <xsl:strip-space elements="*"/>
39
40
41 <!-- - - - - - - - - - - - - - - - - - - - - - -
42 parameters
43 - - - - - - - - - - - - - - - - - - - - - - -->
44 <!-- What to do: 'map' for producing a ditamap with all the version,
45 or 'topic' for producing a single topic (version). -->
46 <xsl:param name="g_sMode">not specified</xsl:param>
47
48 <!-- The id of the topic to convert in 'topic' mode. -->
49 <xsl:param name="g_idTopic">not specified</xsl:param>
50
51
52 <!-- - - - - - - - - - - - - - - - - - - - - - -
53 base operation is to fail on nodes w/o explicit matching.
54 - - - - - - - - - - - - - - - - - - - - - - -->
55
56 <xsl:template match="*">
57 <xsl:message terminate="yes"><xsl:call-template name="error-prefix"/>unhandled element</xsl:message>
58 </xsl:template>
59
60
61 <!-- - - - - - - - - - - - - - - - - - - - - - -
62 Match the root element (chapter) and prodcess it's sect1 entries according to the mode.
63 - - - - - - - - - - - - - - - - - - - - - - -->
64 <xsl:template match="/chapter">
65 <xsl:choose>
66
67 <!-- map: Generate a ditamap for all the versions. -->
68 <xsl:when test="$g_sMode = 'map'">
69 <xsl:text disable-output-escaping='yes'>&lt;!DOCTYPE map PUBLIC "-//OASIS//DTD DITA Map//EN" "map.dtd"&gt;
70 </xsl:text>
71 <xsl:element name="map" >
72 <xsl:element name="title"><xsl:text>Change Log</xsl:text></xsl:element>
73 <xsl:for-each select="./sect1">
74 <xsl:element name="topicref">
75 <xsl:attribute name="href">
76 <xsl:call-template name="changelog-title-to-filename"/>
77 </xsl:attribute>
78 </xsl:element>
79 </xsl:for-each>
80 </xsl:element>
81 </xsl:when>
82
83 <!-- topic: Translate a topic (version) to DITA. -->
84 <xsl:when test="$g_sMode = 'topic'">
85 <xsl:for-each select="./sect1">
86 <xsl:variable name="sId">
87 <xsl:call-template name="changelog-title-to-id"/>
88 </xsl:variable>
89 <xsl:if test="$sId = $g_idTopic">
90 <xsl:text disable-output-escaping='yes'>&lt;!DOCTYPE topic PUBLIC "-//OASIS//DTD DITA Topic//EN" "topic.dtd"&gt;
91</xsl:text>
92 <xsl:element name="topic">
93 <xsl:attribute name="id">
94 <xsl:value-of select="$sId" />
95 </xsl:attribute>
96
97 <xsl:element name="title">
98 <xsl:value-of select="title/text()"/>
99 </xsl:element>
100
101 <xsl:element name="body">
102 <xsl:apply-templates mode="topic" select="*"/>
103 </xsl:element>
104 </xsl:element>
105
106 </xsl:if>
107 </xsl:for-each>
108 </xsl:when>
109
110 <!-- ids: List of IDs (text, not xml - ugly). -->
111 <xsl:when test="$g_sMode = 'ids'">
112 <xsl:for-each select="./sect1">
113 <xsl:variable name="sId">
114 <xsl:call-template name="changelog-title-to-id"/>
115 </xsl:variable>
116 <xsl:value-of disable-output-escaping='yes' select="concat($sId, '&#x0a;')"/>
117 </xsl:for-each>
118 </xsl:when>
119
120 <!-- Otherwise: bad input -->
121 <xsl:otherwise>
122 <xsl:message terminate="yes">Unknown g_sMode value: '<xsl:value-of select="$g_sMode"/></xsl:message>
123 </xsl:otherwise>
124 </xsl:choose>
125 </xsl:template>
126
127
128 <!-- - - - - - - - - - - - - - - - - - - - - - -
129 Section translation to topic.
130 - - - - - - - - - - - - - - - - - - - - - - -->
131 <xsl:template mode="topic" match="sect1/title">
132 <xsl:if test="*">
133 <xsl:message terminate="yes"><xsl:call-template name="error-prefix"/>Unexpected title child elements!</xsl:message>
134 </xsl:if>
135 <!-- already generated, so we only need to assert sanity and skip it. -->
136 </xsl:template>
137
138 <xsl:template mode="topic" match="para">
139 <xsl:element name="p">
140 <xsl:apply-templates mode="topic" select="node()|@*"/>
141 </xsl:element>
142 </xsl:template>
143
144 <xsl:template mode="topic" match="para/text()">
145 <xsl:value-of select="."/>
146 </xsl:template>
147
148 <xsl:template mode="topic" match="itemizedlist">
149 <xsl:element name="ul">
150 <xsl:apply-templates mode="topic" select="node()|@*"/>
151 </xsl:element>
152 </xsl:template>
153
154 <xsl:template mode="topic" match="listitem">
155 <xsl:element name="li">
156 <xsl:apply-templates mode="topic" select="node()|@*"/>
157 </xsl:element>
158 </xsl:template>
159
160
161 <!-- - - - - - - - - - - - - - - - - - - - - - -
162 Helper functions.
163 - - - - - - - - - - - - - - - - - - - - - - -->
164
165 <!-- Extracts the version part of a changelog section title. -->
166 <xsl:template name="get-version-from-changelog-title">
167 <xsl:param name="sTitle" select="./title/text()"/>
168 <xsl:variable name="sAfterVersion" select="normalize-space(substring-after($sTitle, 'Version '))"/>
169 <xsl:variable name="sVersion" select="substring-before($sAfterVersion, ' (')"/>
170 <xsl:if test="$sVersion = ''">
171 <xsl:message terminate="yes"><xsl:call-template name="error-prefix"/>Unable to extract version from section title!</xsl:message>
172 </xsl:if>
173
174 <xsl:value-of select="$sVersion"/>
175 </xsl:template>
176
177 <!-- Outputs an id for a changelog section based on the title. -->
178 <xsl:template name="changelog-title-to-id">
179 <xsl:param name="sTitle" select="./title/text()"/>
180 <xsl:text>changelog-version-</xsl:text>
181 <xsl:variable name="sVersion">
182 <xsl:call-template name="get-version-from-changelog-title">
183 <xsl:with-param name="sTitle" select="$sTitle"/>
184 </xsl:call-template>
185 </xsl:variable>
186 <xsl:value-of select="translate($sVersion, '.', '_')"/>
187 </xsl:template>
188
189 <!-- Outputs a filename for a changelog section based on the title. -->
190 <xsl:template name="changelog-title-to-filename">
191 <xsl:param name="sTitle" select="./title/text()"/>
192 <xsl:call-template name="changelog-title-to-id">
193 <xsl:with-param name="sTitle" select="$sTitle"/>
194 </xsl:call-template>
195 <xsl:text>.dita</xsl:text>
196 </xsl:template>
197
198 <!--
199 Debug/Diagnostics: Return the path to the specified node (by default the current).
200 -->
201 <xsl:template name="get-node-path">
202 <xsl:param name="Node" select="."/>
203 <xsl:for-each select="$Node">
204 <xsl:for-each select="ancestor-or-self::node()">
205 <xsl:choose>
206 <xsl:when test="name(.) = ''">
207 <xsl:value-of select="concat('/text(',')')"/>
208 </xsl:when>
209 <xsl:otherwise>
210 <xsl:value-of select="concat('/', name(.))"/>
211 <xsl:choose>
212 <xsl:when test="@id">
213 <xsl:text>[@id=</xsl:text>
214 <xsl:value-of select="@id"/>
215 <xsl:text>]</xsl:text>
216 </xsl:when>
217 <xsl:otherwise>
218 <!-- Use generate-id() to find the current node position among its siblings. -->
219 <xsl:variable name="id" select="generate-id(.)"/>
220 <xsl:for-each select="../node()">
221 <xsl:if test="generate-id(.) = $id">
222 <xsl:text>[</xsl:text><xsl:value-of select="position()"/><xsl:text>]</xsl:text>
223 </xsl:if>
224 </xsl:for-each>
225 </xsl:otherwise>
226 </xsl:choose>
227 </xsl:otherwise>
228 </xsl:choose>
229 </xsl:for-each>
230 </xsl:for-each>
231 </xsl:template>
232
233 <!--
234 Debug/Diagnostics: Return error message prefix.
235 -->
236 <xsl:template name="error-prefix">
237 <xsl:param name="Node" select="."/>
238 <xsl:text>error: </xsl:text>
239 <xsl:call-template name="get-node-path">
240 <xsl:with-param name="Node" select="$Node"/>
241 </xsl:call-template>
242 <xsl:text>: </xsl:text>
243 </xsl:template>
244
245</xsl:stylesheet>
246
Note: See TracBrowser for help on using the repository browser.

© 2023 Oracle
Contact – Privacy policy – Terms of Use