VirtualBox

source: kBuild/vendor/grep/2.12/m4/fdopen.m4

Last change on this file was 2595, checked in by bird, 12 years ago

gnu grep version 2.12 (grep-2.12.tar.xz, md5sum=8d2f0346d08b13c18afb81f0e8aa1e2f)

File size: 1.3 KB
Line 
1# fdopen.m4 serial 2
2dnl Copyright (C) 2011-2012 Free Software Foundation, Inc.
3dnl This file is free software; the Free Software Foundation
4dnl gives unlimited permission to copy and/or distribute it,
5dnl with or without modifications, as long as this notice is preserved.
6
7AC_DEFUN([gl_FUNC_FDOPEN],
8[
9 AC_REQUIRE([gl_STDIO_H_DEFAULTS])
10 AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
11 AC_REQUIRE([gl_MSVC_INVAL])
12 if test $HAVE_MSVC_INVALID_PARAMETER_HANDLER = 1; then
13 REPLACE_FDOPEN=1
14 else
15 dnl Test whether fdopen() sets errno when it fails due to a bad fd argument.
16 AC_CACHE_CHECK([whether fdopen sets errno], [gl_cv_func_fdopen_works],
17 [
18 AC_RUN_IFELSE(
19 [AC_LANG_SOURCE([[
20#include <stdio.h>
21#include <errno.h>
22int
23main (void)
24{
25 FILE *fp;
26 errno = 0;
27 fp = fdopen (-1, "r");
28 if (fp != NULL)
29 return 1;
30 if (errno == 0)
31 return 2;
32 return 0;
33}]])],
34 [gl_cv_func_fdopen_works=yes],
35 [gl_cv_func_fdopen_works=no],
36 [case "$host_os" in
37 mingw*) gl_cv_func_fdopen_works="guessing no" ;;
38 *) gl_cv_func_fdopen_works="guessing yes" ;;
39 esac
40 ])
41 ])
42 case "$gl_cv_func_fdopen_works" in
43 *no) REPLACE_FDOPEN=1 ;;
44 esac
45 fi
46])
47
48dnl Prerequisites of lib/fdopen.c.
49AC_DEFUN([gl_PREREQ_FDOPEN], [])
Note: See TracBrowser for help on using the repository browser.

© 2024 Oracle Support Privacy / Do Not Sell My Info Terms of Use Trademark Policy Automated Access Etiquette